不安定な Wayland モジュール

このモジュールはバージョン 0.62.0 以降で使用できます。

このモジュールは、Wayland プロトコルの xml を検索し、wayland-scanner を使用して .c ファイルと .h ファイルを生成するヘルパー関数を提供します

注: このモジュールは不安定です。テクノロジープレビューとしてのみ提供されます。そのAPIはリリース間で自由に変更されるか、Mesonから完全に削除される場合があります。

クイックユース

project('hello-wayland', 'c')

wl_dep = dependency('wayland-client')
wl_mod = import('unstable-wayland')

xml = wl_mod.find_protocol('xdg-shell')
xdg_shell = wl_mod.scan_xml(xml)

executable('hw', 'main.c', xdg_shell, dependencies : wl_dep)

メソッド

find_protocol

xml = wl_mod.find_protocol(
  'xdg-decoration',
  state : 'unstable',
  version : 1,
)

この関数は1つの位置引数、プロトコルの基本名を必要とします。

次のキーワード引数を使用します

  • state プロトコルの現在の状態を指定するオプションの引数。'stable'、'staging'、または 'unstable' のいずれか。デフォルトは 'stable' です。
  • version 下位互換性のないバージョン番号を整数で指定します。ステージングと不安定に必要ですが、安定には許可されていません。

返り値: file。scan_xml に渡すことができます

scan_xml

generated = wl_mod.scan_xml(
  'my-protocol.xml',
  client : true,
  server : true,
  public : false,
  include_core_only : true,
)

この関数は、string または file タイプの1つ以上の引数を受け取ります。

次のキーワード引数を使用します

  • public 生成されたコードのスコープを指定するオプションの引数。デフォルトは false です。
  • client クライアント側のヘッダーファイルが生成されるかどうかを指定するオプションの引数。デフォルトは true です。
  • server サーバー側のヘッダーファイルが生成されるかどうかを指定するオプションの引数。デフォルトは false です。
  • include_core_only 生成されたヘッダーに wayland-<client|server>.h ではなく wayland-<client|server>-core.h のみを含めることを指定するオプションの引数。デフォルトは true です。0.64.0 以降

返り値: 生成されたヘッダーファイルには <name>-<client|server>-protocol.h という名前が付けられます。 custom_tgt のリストで、ソース、クライアント側ヘッダー、サーバー側ヘッダーの順になっています。

検索結果